Script Backup ke Cloud MikroTik Otomatis

Berikut adalah script otomatisasi (script dan scheduler) untuk melakukan backup ke Cloud MikroTik secara otomatis misalnya backup otomatis setiap minggu. Sistem akan membuat nama file unik berdasarkan tanggal dan waktu, lalu menghapus file backup lokal yang tersisa supaya memori penyimpanan router tidak cepat penuh.

Membuat Script Backup

Pertama, kita akan membuat skript yang bertugas membuat file backup dan menguploadnya ke Cloud MikroTik.

• Melalui Winbox -> buka menu System -> Scripts -> klik tombol + (Add New).
  • Isi kolom Name dengan: AutoCloudBackup
  • Pastikan kolom Policies centang hanya: read, write, policy, test.
  • Copy dan paste script di bawah ini ke dalam kotak Source:

# Password rubah sesuai keinginan Anda
:local backupPassword "PasswordAnda"

# Mengambil data tanggal dan waktu
:local dateTime [/system clock get date]
:local timeTime [/system clock get time]

# Mengubah format tanggal
:local cleanDate ""
:for i from=0 to=([:len $dateTime] - 1) do={
    :local char [:pick $dateTime $i ($i + 1)]
    :if ($char = "/" || $char = " " || $char = ":") do={
        :set cleanDate ($cleanDate . "-")
    } else={
        :set cleanDate ($cleanDate . $char)
    }
}

# Mengubah format waktu
:local cleanTime ""
:for i from=0 to=([:len $timeTime] - 1) do={
    :local char [:pick $timeTime $i ($i + 1)]
    :if ($char = ":") do={
        :set cleanTime ($cleanTime . "-")
    } else={
        :set cleanTime ($cleanTime . $char)
    }
}

# Menyusun nama file (Contoh: Backup-Auto-2026-07-25-15-30)
:local fileName "Backup-Auto-$cleanDate-$cleanTime"

:log info "Memulai proses Cloud Backup otomatis dengan nama $fileName..."

# Menghapus file backup lama yang ada di Cloud MikroTik untuk mengosongkan slot
:log info "Delete file backup cloud lama..."
/system backup cloud remove [find]
:delay 3s

# Eksekusi backup dan upload ke Cloud MikroTik (RouterOS v7)
/system backup cloud upload-file action=create-and-upload name=$fileName password=$backupPassword
:delay 10s

:log info "Proses Cloud Backup Otomatis Sukses."

Klik Apply lalu OK

Cara memastikan script berjalan dengan baik tanpa nunggu minggu depan, kita hanya klik tombol Run Script yang baru saja kita buat. Buka menu Log atau menu Files -> Cloud Backup untuk memastikan file backup baru Anda telah berhasil diupload ke server cloud MikroTik.

Membuat Scheduler Seminggu Sekali

Kita perlu menjadwalkan agar skrip tersebut berjalan otomatis setiap minggu.

1. Buka menu System -> Scheduler di Winbox.
2. Klik ikon [+] (Add New).
3. Isi parameter berikut:
   • Name: JadwalBackupMingguan
   • Start Date: Biarkan tanggal hari ini (atau pilih tanggal mulai yang diinginkan).
   • Start Time: 02:00:00 (Sangat disarankan dieksekusi saat dini hari ketika trafik jaringan sedang sepi).
   • Interval: 7d 00:00:00 (Artinya dieksekusi berulang setiap 7 hari sekali).
   • On Event: AutoCloudBackup (Ketikkan nama sama persis script yang telah dibuat)
   • Policies: Centang read, write, policy, dan test.
4. Klik Apply lalu OK.